Владимир спрашивает:

Я нашел два подходящих макроса.

Sub upHF()
'Обновление полей в надписях, содержащихся в колонтитулах
Dim oRng As Word.Range  'объявляем объект Word типа Range
Dim oShp As Word.Shape  'объявляем объект Word типа Shape
On Error Resume Next    'игнорируем ошибку
For Each oRng In ActiveDocument.StoryRanges 'для каждого дипазона во всех 
областях активного документа
    Do 'начинаем цикл, пока условие (oRng Is Nothing) не будет выполнено 
(см. внизу)
        oRng.Fields.Update  'обновляем поля
        For Each oShp In oRng.ShapeRange    'для каждого граф.объекта в 
диапазоне
              oShp.TextFrame.TextRange.Fields.Update    'обновляем поля в 
текстовых блоках в граф.объектах
       Next oShp
        Set oRng = oRng.NextStoryRange  'проверяем остальные области 
документа
    Loop Until oRng Is Nothing  'условие
Next oRng
On Error GoTo 0
End Sub

Макрос от Greg Maxey:

Sub myUpdateFields()
Dim rngStory As Word.Range
Dim oShp As Word.Shape
For Each rngStory In ActiveDocument.StoryRanges
    Do
        On Error Resume Next
        rngStory.Fields.Update
        Select Case rngStory.StoryType
            Case 6, 7, 8, 9, 10, 11
                If rngStory.ShapeRange.Count > 0 Then
                    For Each oShp In rngStory.ShapeRange
                        If oShp.TextFrame.HasText Then
                            oShp.TextFrame.TextRange.Fields.Update
                        End If
                    Next oShp
                End If
            Case Else
                'Do Nothing
        End Select
        On Error GoTo 0
        'Get next linked story (if any)
        Set rngStory = rngStory.NextStoryRange
    Loop Until rngStory Is Nothing
Next rngStory
End Sub