1 Тема от сонейка

  • сонейка
  • рядовой
  • Неактивен
  • Зарегистрирован: 17.09.2010
  • Сообщений: 2

Тема: макрос пересохраняющий все .docx файлы в .doc

Возможно ли в Word'е написать макрос пересохраняющий все .docx файлы в заданной директории в .doc файлы.
Как это осуществить?

Заранее спасибо!

2 Ответ от viter.alex

  • макрос пересохраняющий все .docx файлы в .doc
  • viter.alex
  • Модератор
  • Неактивен
  • Откуда: Харьков, Украина
  • Зарегистрирован: 21.12.2009
  • Сообщений: 884
  • Поблагодарили: 140

Re: макрос пересохраняющий все .docx файлы в .doc

Возможно. Например таким макросом для Word 2007:

Sub SaveDocxToDoc()
  Dim sPath As String
  Dim sFileName As String
  Dim counter As Long
  
  With Application.FileDialog(msoFileDialogFolderPicker)
    .Title = "Выберите папку"
    .AllowMultiSelect = False
    If .Show Then
      sPath = .SelectedItems(1)
    Else
      Exit Sub
    End If
  End With
  
  sFileName = Dir(sPath & Application.PathSeparator & "*.docx")
  
  Do While Len(sFileName) > 0
    With Documents.Open(sPath & Application.PathSeparator & sFileName, AddToRecentFiles:=False)
      .SaveAs Mid(.FullName, 1, InStrRev(.FullName, ".") - 1) & ".doc", wdFormatDocument97
      .Close
    End With
    sFileName = Dir
    DoEvents
    counter = counter + 1
  Loop
  If counter > 0 Then
    MsgBox "Пересохранение docx в doc завершено." & vbNewLine & "Обработано " & counter & " документов.", vbInformation, "Пересохранение docx в doc"
  Else
    MsgBox "В папке """ & sPath & """ файлы docx не обнаружены.", vbInformation, "Пересохранение docx в doc"
  End If
End Sub
Лучше день потерять — потом за пять минут долететь!

Сайтviter.alex

3 Ответ от сонейка

  • сонейка
  • рядовой
  • Неактивен
  • Зарегистрирован: 17.09.2010
  • Сообщений: 2

Re: макрос пересохраняющий все .docx файлы в .doc

viter.alex пишет:

Возможно. Например таким макросом для Word 2007:

Работает!
Спасибо!