1

Тема: Как перенести таблицу Excel в Word

Добрый день подскажите,
как правильно перенести таблицу Excel в Word, чтоб можно было в дальнейшем корретировать её.

2

Re: Как перенести таблицу Excel в Word

корректировать в Exel ее собираетесь??? или в Word???

3

Re: Как перенести таблицу Excel в Word

Скопируйте диапазон в Excel, перейдите в Word и вставьте его через специальную вставку, выбрав опцию "Связать". Изменения в таблице Excel будут отражаться в таблице, вставленной в Word

Лучше день потерять — потом за пять минут долететь!

4

Re: Как перенести таблицу Excel в Word

В моей любимой книге “Word 2003/2007. Народные советы” на стр.152 написано:
Как вставить таблицу Excel в документ
Этот способ может пригодиться тем пользователям, которые периодически используют в своих документах широкоформатные таблицы, созданные в программе Microsoft Excel.
К сожалению, обычный способ копирования таблицы из Excel и вставки ее в документ Word имеет существенные недостатки. Самые очевидные — по ширине таблица выходит за пределы страницы, а ее формат (шрифт, интервал) отличается от используемого формата документа.
Однако можно избавиться от этих недостатков, если вставить таблицу в документ как графический объект.
В редакторе Word 2003
1.    В меню Вставка выберите команду Объект. Откроется диалоговое окно Вставка объекта.
2.    Перейдите на вкладку Создание из файла.
3.    Нажмите кнопку Обзор, чтобы найти и выбрать файл таблицы Excel. После того как в поле Имя файла появится строка местоположения найденного файла, нажмите кнопку ОК.
Таблица будет вставлена в документ как рисунок. Вы можете изменять его размеры, перемещать и выполнять иные действия. Если дважды щелкнуть мышью по рисунку таблицы, то вы сможете отредактировать исходные данные вашей таблицы прямо в документе Word. При этом окно редактора изменится и примет вид программы Excel. После редактирования исходных данных щелкните указателем мыши за пределами таблицы, чтобы вернуться в режим редактирования документа Word.
В редакторе Word 2007
1.    Перейдите на вкладку ленты Вставка.
2.    В группе команд Текст нажмите кнопку Вставить объект. Откроется диалоговое окно Вставка объекта.
3.    Нажмите кнопку Обзор, чтобы найти и выбрать файл таблицы Excel. После того как в поле Имя файла появится строка местоположения найденного файла, нажмите кнопку ОК.

5

Re: Как перенести таблицу Excel в Word

Спасибо за ответы  !!!!
Здорово всё получилось!!!!!!!!
Спасибо!!!!!!

Отредактировано Вулк (04.06.2010 12:51:15)

6

Re: Как перенести таблицу Excel в Word

Подскажите, как можно в Excel или в Wordе  при вводе числа получить значение данного числа  прописью

Например: 45 - сорок пять и т.д.

С уважением Владимир.

7

Re: Как перенести таблицу Excel в Word

Читайте на сайте (и пользуйтесь поиском): Число или сумма прописью.

8

Re: Как перенести таблицу Excel в Word

а можно использовать и макросы других авторов (найдено в инете, в открытом доступе, насколько я помню на VBstreet):

Sub SummaString(Summa$, source As Long, Rod%, w1$, w2to4$, w5to10$)
'
' "Сумма прописью":
'  преобразование числа из цифрого вида в символьное
' ==================================================
' Исходные данные:
'  Source - число от 0 до 2147483647 (2^31-1)
   ' Eсли нужно оперировать с числами > 2 147 483 647
   ' замените описание переменных Source и TempValue на "AS DOUBLE"
'
'    далее нужно задать информацию о единице изменения
'  Rod%   = 1 - мужской, = 2 - женский, = 3 - средний
'     название единицы изменения:
'  w1$     - именительный падеж единственное число (= 1)
'  w2to4$  - родительный падеж единственное число (= 2-4)
'  w5to10$ - родительный падеж множественное число ( = 5-10)
'
'  Rod% должен быть задано обязательно, название единицы может быть
'       не задано = ""
' ———————————————-
' Результат: Summa$ - запись прописью
'
'================================
   Dim TempValue As Long
   '
   If source& = 0 Then
     Summa$ = RTrim$("ноль " + w5to10$): Exit Sub
   End If
   '
   TempValue = source: Summa$ = ""
   ' единицы
   Call SummaStringThree(Summa$, TempValue, Rod%, w1$, w2to4$, w5to10$)
   If TempValue = 0 Then Exit Sub
   ' тысячи
   Call SummaStringThree(Summa$, TempValue, 2, "тысяча", "тысячи", "тысяч")
   If TempValue = 0 Then Exit Sub
   ' миллионы
   Call SummaStringThree(Summa$, TempValue, 1, "миллион", "миллиона", "миллионов")
   If TempValue = 0 Then Exit Sub
   ' миллиардов
   Call SummaStringThree(Summa$, TempValue, 1, "миллиард", "миллиарда", "миллиардов")
   If TempValue = 0 Then Exit Sub
   '
   ' Eсли нужно оперировать с числами > 2 147 483 647
   ' измените тип переменных (см. выше) и добавьте эту строку для триллионов:
   ' CALL SummaStringThree(Summa$, TempValue#, 1, "трилллион", "триллиона", "триллионов")
   ' IF TempValue# = 0 THEN EXIT SUB
   '
   ' Что идет после триллионов, я плохо представляю...
   '
End Sub
Sub SummaStringThree(Summa$, TempValue As Long, Rod%, w1$, w2to4$, w5to10$)
'
'  Формирования строки для трехзначного числа:
'  (последний трех знаков TempValue
   ' Eсли нужно оперировать с числами > 2 147 483 647
   ' замените в описании на  TempValue AS DOUBLE
'====================================
   Dim Rest%, Rest1%, EndWord$, s1$, s10$, s100$
   '
   Rest% = TempValue& Mod 1000
   TempValue& = TempValue& \ 1000
   If Rest% = 0 Then    ' последние три знака нулевые
     If Summa$ = "" Then Summa$ = w5to10$ + " "
     Exit Sub
   End If
   '
   ' начинаем подсчет с Rest
   EndWord$ = w5to10$
   ' сотни
   Select Case Rest% \ 100
     Case 0: s100$ = ""
     Case 1: s100$ = "сто "
     Case 2: s100$ = "двести "
     Case 3: s100$ = "триста "
     Case 4: s100$ = "четыреста "
     Case 5: s100$ = "пятьсот "
     Case 6: s100$ = "шестьсот "
     Case 7: s100$ = "семьсот "
     Case 8: s100$ = "восемьсот "
     Case 9: s100$ = "девятьсот "
   End Select
   '
   ' десятки
   Rest% = Rest% Mod 100: Rest1% = Rest% \ 10
   s1$ = ""
   Select Case Rest1%
     Case 0: s10$ = ""
     Case 1  ' особый случай
       Select Case Rest%
         Case 10: s10$ = "десять "
         Case 11: s10$ = "одиннадцать "
         Case 12: s10$ = "двенадцать "
         Case 13: s10$ = "тринадцать "
         Case 14: s10$ = "четырнадцать "
         Case 15: s10$ = "пятнадцать "
         Case 16: s10$ = "шестнадцать "
         Case 17: s10$ = "семнадцать "
         Case 18: s10$ = "восемнадцать "
         Case 19: s10$ = "девятнадцать "
       End Select
     Case 2: s10$ = "двадцать "
     Case 3: s10$ = "тридцать "
     Case 4: s10$ = "сорок "
     Case 5: s10$ = "пятьдесят "
     Case 6: s10$ = "шестьдесят "
     Case 7: s10$ = "семьдесят "
     Case 8: s10$ = "восемьдесят "
     Case 9: s10$ = "девяносто "
   End Select
   '
   If Rest1% <> 1 Then  ' единицы
     Select Case Rest% Mod 10
       Case 1
         Select Case Rod%
           Case 1: s1$ = "один "
           Case 2: s1$ = "одна "
           Case 3: s1$ = "одно "
         End Select
         EndWord$ = w1$
       Case 2
         If Rod% = 2 Then s1$ = "две " Else s1$ = "два "
         EndWord$ = w2to4$
       Case 3: s1$ = "три ": EndWord$ = w2to4$
       Case 4: s1$ = "четыре ": EndWord$ = w2to4$
       Case 5: s1$ = "пять "
       Case 6: s1$ = "шесть "
       Case 7: s1$ = "семь "
       Case 8: s1$ = "восемь "
       Case 9: s1$ = "девять "
     End Select
   End If
   '
   ' сборка строки
   Summa$ = RTrim$(RTrim$(s100$ + s10$ + s1$ + EndWord$) + " " + Summa$)
End Sub

Ну а это для теста приведенных выше процедур

Sub tttttest()
Dim source As Long
Dim Summa As String
source = 2010
Call SummaString(Summa, source, 1, "", "", "")
Mid$(Summa$, 1) = Chr$(Asc(Summa$) - 32)
MsgBox Summa
End Sub