Выделить текст, но не печатать выделение

Например, макрос, который приведен далее: если выделена часть текста, то макрос печатает выделенный текст. Иначе, печатается весь документ. Перед печатью весь шрифт переводится в шрифт по умолчанию (т.е., черный), а после печати - изменения в шрифте откатываются.
'---------------------------------------------------------------
Sub PrintInNormalizedFont()
Dim prtrange As Variant
If Selection.range.End > Selection.range.Start Then
    prtrange = wdPrintSelection
    Selection.Font.Color = wdColorAutomatic
Else
    prtrange = wdPrintAllDocument
    ActiveDocument.range.Font.Color = wdColorAutomatic
End If
Application.PrintOut FileName:="", range:=prtrange, Item:= _
        wdPrintDocumentWithMarkup, Copies:=1, Pages:="", PageType:= _
        wdPrintAllPages, Collate:=True, Background:=False, PrintToFile:=False, _
        PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
        PrintZoomPaperHeight:=0
ActiveDocument.Undo
End Sub
'---------------------------------------------------------------

Откат вручную делать не надо: это делает оператор макроса
ActiveDocument.Undo
Если у вас есть другие способы выделения текста, то надо соответствующий VBA-код указать. Напр., если у вас используется маркировка, то вместо строк
Selection.Font.Color = wdColorAutomatic
и
ActiveDocument.range.Font.Color = wdColorAutomatic

следует кодировать соответственно
Selection.range.highlightcolorindex = wdNoHighlight
и
ActiveDocument.range.highlightcolorindex = wdNoHighlight

Если же вы применяете совместно различные способы выделения (напр., цвет шрифта и маркировку), то следует в VBA-коде указывать оба способа, но тогда потребуется соответственно увеличить число операторов  ActiveDocument.Undo

yshindin,
спасибо за ответы!
всё работает!
ещё одна просьба, можно как-то макрос изменить, чтобы не сразу печатало, а появлялось диалоговое окно печати(изменить принтер, число копий, кол-во страниц для печати), не всегда удобно печатать только по выделению.

Да, конечно, надо не забыть оператор нормализации шрифта или маркировки при этом - напр., указать (до оператора вызова диалога печати) сразу для всего документа:
ActiveDocument.range.Font.Color = wdColorAutomatic

Попробуйте вот этот код:
'------------------------------------------------------------------------
Sub PrintInNormalizedFont()
ActiveDocument.range.Font.Color = wdColorAutomatic
Dialogs(wdDialogFilePrint).Show
ActiveDocument.Undo
End Sub
'------------------------------------------------------------------------

yshindin,
последний код я ещё переделала под маркер, вынесла этот макрос кнопкой на панель быстрого запуска - вообще получилось то, что я хотела.
Большое спасибо! Проблема решена!