1

Тема: Автоматизация проверки правильности выполнения задания

Помогите пожалуйста сделать макрос для автоматизация проверки правильности выполнения задания по форматированию документа в MS Word.
Шрифт Times New Roman
Размер шрифта 14
Выравнивание по ширине
Интервалы перед и после 0 пт
Муждустрочный 1,5

2

Re: Автоматизация проверки правильности выполнения задания

А зачем проверять? Проще сразу устанавливать, например так

Sub FormatDocument()
    Application.ScreenUpdating = False
    With ActiveDocument.Range
        With .Font
            .Name = "Times New Roman"
            .Size = 14
        End With
        With .ParagraphFormat
            .Alignment = wdAlignParagraphJustify
            .SpaceBefore = 0
            .SpaceAfter = 0
            .LineSpacingRule = wdLineSpace1pt5
        End With
    End With
    Application.ScreenUpdating = True
End Sub

3

Re: Автоматизация проверки правильности выполнения задания

Мне нужно сделать макрос который проверяет правильно оформлен документ или нет.

4

Re: Автоматизация проверки правильности выполнения задания

Как вариант. С расшифровкой какие именно ошибки в каком абзаце находятся, возиться лень, если хотитеподумайте в стороны коллекций

Sub FormatDocument()
    Dim i As Long, s As String, ok As Boolean
    Application.ScreenUpdating = False
    For i = 1 To ActiveDocument.Paragraphs.Count
        With ActiveDocument.Paragraphs(i).Range
            With .Font
                ok = .Name = "Times New Roman" And .Size = 14
            End With
            With .ParagraphFormat
                ok = ok And .Alignment = wdAlignParagraphJustify And .SpaceBefore = 0 _
                And .SpaceAfter = 0 And .LineSpacingRule = wdLineSpace1pt5
            End With
        End With
        If Not ok Then If s = "" Then s = Str(i) Else s = s & ", " & Str(i)
    Next
    Application.ScreenUpdating = True
    MsgBox "Абзацы " & s & " сожержат ошибки"
End Sub

5

Re: Автоматизация проверки правильности выполнения задания

Большое спасибо, вы мне очень помогли.