1

Тема: Как выделить все графические объекты в многостраничном документе?

Переношу сюда вопрос, заданный на сайте http://wordexpert.ru
Подскажите, пожалуйста, как можно выделить все графические объекты в документе (например, во всем документе, страниц 200, оказалась черта в виде графического элемента) и потом ее удалить?
по одной - все линиии (черточки) удаляются после выделения, а вот, чтоб все сразу удалить - слишком долгая история.
Способ "Найти - Заменить", там где выбирается графический объект - не подошел, ворд "не увидел" эту черту как графику. Хотя меню для этого объекта отображается, как для рисунка, автофигуры. Вкладываю приложение.
Возможны ли варианты не макросовые?:)
Спасибо

Отредактировано ronny (07.06.2010 09:57:03)

Post's attachments

cherta.doc 31 Кб, 2 скачиваний с 2010-06-07 

You don't have the permssions to download the attachments of this post.

2

Re: Как выделить все графические объекты в многостраничном документе?

Без макроса этого не сделать. А макросом можно попробовать так:

Sub DeleteThisLine()
  Dim i As Long 'Счётчик
  'Габариты
  Dim nLineWidth As Single, nLineHeight As Single
  'Толщина линии
  Dim oLineThickness As Single
  'Фигура
  Dim curShp As Shape
  
  With Selection.ShapeRange(1)
    nLineWidth = .Width
    nLineHeight = .Height
    oLineThickness = .Line.Weight
  End With
  'Перебираем все рисунки, начиная с конца
  For i = ActiveDocument.Shapes.Count To 1 Step -1
    Set curShp = ActiveDocument.Shapes(i)
    With curShp
      'Если совпадает тип, габариты и толщина линии, то удаляем
      If .Type = msoLine And _
         .Width = nLineWidth And _
         .Height = nLineHeight And _
         .Line.Weight = oLineThickness Then
        .Delete
      End If
    End With
  Next i
  
End Sub

Перед запуском макроса нужно выделить одну линию. Все линии, похожие на неё, будут удалены.

Лучше день потерять — потом за пять минут долететь!

3

Re: Как выделить все графические объекты в многостраничном документе?

viter.alex, спасибо, буду пробовать с макросом,
без макроса действительно нереально выполнить эту команду, все перепробовала smile

4

Re: Как выделить все графические объекты в многостраничном документе?

Кстати, ^g не находил эту линию, потому что он работает с картинками.

Лучше день потерять — потом за пять минут долететь!

5

Re: Как выделить все графические объекты в многостраничном документе?

я на это обратила внимание... по документу, где как раз были рисунки, вставленные именно через Вставку, находились через "Найти", а вот линия - упертая оказалась:)